• 上位/下位インタフェース変更
  重要で本質的な変更です。version 4ではHTTP風リクエストヘッダ文字列を送受する構造を前提としていましたが、version 5は特別な書式が決められていない文字列をやりとりするだけです。
  
  
• システム関数全面見直し
  version 4が持つシステム関数のうち、完全に同一機能のまま引き継がれたものは半数程度です。多くが新規追加、廃止、あるいは機能変更されています。詳細はシステム関数リファレンスで確認して下さい。
  
  最も注意を要するのは文字列処理系の関数です。
  version 4　STR*系（バイト数単位）、MSTR*系（文字数単位）の二系統が存在
  version 5　STR*系（文字数単位）
  STR*系関数が残されましたが、動作はMSTR*系のものになっています。これは内部処理がUNICODE化されたためです。
  
  
• システム変数全廃
  _argv、_argc以外のシステム変数は廃止されました。ただし同等機能を持つシステム関数が追加されています。
  
  
• 空の文字列
  version 4では空の文字列と値無しの区別が不明確でした。version 5ではこれが厳格に区別されます。
  
  
• 関数/変数名の先頭に数値を使えない
  version 4では使用可能でした（そもそも12hourというシステム変数があったほどです）。これはversion 5では禁止となりました。
  
  他にも変数名/関数名として使用不可能になった文字が存在します。
  
  
• 機能制限設定機能は未搭載
  考えた結果、とりあえず未実装としました。
  
  
• そのほか...
  version 4のパーサが弱かったおかげで見逃されていたエラーが顕在化する可能性があります。

• extern "C" __declspec(dllexport) BOOL __cdecl load(HGLOBAL h, long len)
  
  文に初期化を指示します。
  文をLoadLibraryして使用を開始する直前に、この関数を一度だけ必ず実行してください。
  hには「文がカレントとして認識するディレクトリ絶対パス」を、lenはhの長さを渡してください。
  
  hの領域開放は文側で行ないますので、呼び出し側では使い放しでかまいません。
  
  
• extern "C" __declspec(dllexport) BOOL __cdecl unload()
  
  文に終了を指示します。
  文をFreeLibraryする直前に一度だけ実行してください。
  
  
• extern "C" __declspec(dllexport) HGLOBAL __cdecl request(HGLOBAL h, long *len)
  
  文に処理を指示し、結果を得ます。
  hには処理対象の文字列を、*lenにhの長さを渡してください。
  
  渡したhの領域開放は文側で行ないますので、呼び出し側では使い放しでかまいません。
  
  処理結果は戻り値で得られます。処理結果の長さは*lenに格納されています（つまりこの値は書き換えられます）。 戻り値を取得した後、領域を*lenで示されるサイズで開放(GlobalFree)してください。

// dics
dic, basis.dic
dic, control./*doc*/ayc

// option parameters
charset, UTF-8
msglang, english
log, executelog.txt
iolog, off
fncdepth, 16

• charset, name
  
  標準の文字コードを設定します。
  以下の予約値からいずれかを指定します。指定が無い場合はShift_JISとして扱われます。
  
  
  • Shift_JIS / ShiftJIS / SJIS
    シフトJISコード。
  • UTF-8
    UTF-8。
  • default
    実行OSのデフォルト文字コード。
  
  
• dic, filename
  
  辞書ファイルfilenameをロードします。
  辞書ファイルは文スクリプトが記述されたプログラムソースファイルで、文はここのプログラムされた内容を元に動作します。
  辞書ファイルはいくつでも指定し、読み込むことができます。
  
  filenameはloadで指定されたパス位置からの相対バスで指定します。
  
  標準の辞書ファイルはcharsetで指定した文字コードで記述されたプレーンテキストファイルです。この他に、一定の法則でスクランブルをかけた 暗号化ファイルを読み込むことができます。
  
  
• msglang, language
  
  ログに記録されるエラーメッセージ類の言語を選択します。
  以下の予約値からいずれかを指定します。指定が無い場合はjapaneseとして扱われます。
  
  
  • japanese
    日本語。
  • english
    英語。
  
  
• log, logfilename
  
  実行ログをファイルlogfilenameに記録します。
  charsetで指定した文字コードで書き込まれます。
  
  logfilenameはloadで指定されたパス位置からの相対バスで指定します。
  
  
• iolog, [on|off]
  
  load、unload、request実行時の入出力文字列と処理時間をログに記録するかを設定します。
  onで記録します。デフォルトではonになっていますので、不要の場合にoffとしてください。
  
  
• fncdepth, depth
  
  関数呼び出しの深さ上限を数値で指定します。
  デフォルト値は32です。最低値は2で、これより小さな値や不正な値を指定した場合も2として扱われます。
  
  
• checkparser, [on|off]
  
  辞書の構文解析結果レポートをログに記録するかを設定します。
  onで記録します。デフォルトではoffになっています。
  
  

request
{
    "Hello World"
}

load
{
    str = "Hello"
}

request
{
    str + " " + _argv[0] + "!"
}

request{"Hello World"}

req/
uest          {
"/
Hello World"  }

"ABCD
    EFG"

request
{
    answer = 1 + 2
    "答えは" + answer + "です。"
}

request
{
    answer = 1 + 2; "答えは" + answer + "です。"
}

request
{
    hello
}

hello
{
    "Hello World"
}

request
{
    combine("Hello", "World")
}

combine
{
    _argv[0] + " " + _argv[1]
}

request
{
    factorial(5)
}

factorial
{
    if !_argv[0]
        1
    else
        factorial(_argv[0] - 1)*_argv[0]
}

request
{
    "Hello World"
    "こんにちは世界"
    "Hallo Welt"
}

• デフォルトでは無作為に選択します。
  
  
• nonoverlap
  すべての候補が出力されるまでは、同じ候補を選択しなくなります。

  request : nonoverlap
  {
      "Hello World"
      "こんにちは世界"
      "Hallo Welt"
  }
  

  上のように、関数名の後ろに": nonoverlap"を付け加えます。

• sequential
  記述された順に出力します。最後まで出力したらまた先頭に戻ります。

  request : sequential
  {
      "Hello World"
      "こんにちは世界"
      "Hallo Welt"
  }
  

  上のように、関数名の後ろに": sequential"を付け加えます。

• void
  何も出力しなくなります。
  以下の例の場合、requestは3つの候補のどれも出力しません。

  request : void
  {
      "Hello World"
      "こんにちは世界"
      "Hallo Welt"
  }
  

  「何も実行しない」ではなく、「何も出力しない」であることに注意してください。
  内部に書かれた関数や数式は処理されます。

  increment_i : void
  {
      i++
      i
  }
  

  上の関数increment_iはiに1を加算します。voidが無い場合、この関数は加算結果を返しますが、voidを指定すると値を返さず、 ただ加算を行うのみとなります。

• array
  出力候補をすべて結合した汎用配列を関数の返値とします。
  

  request : array
  {
  　　"This is a pen."
  　　("A","B","C")
  　　3.14
  }
  

  出力は汎用配列 ("This is a pen.", "A", "B", "C", 3.14) となります。
  
  

request : sequential
{
    "1"
    "2"
    "3"
    --
    "A"
    "B"
}

"1A" "2A" "3A" "1B" "2B" "3B" "1A" "2A" …

request : sequential
{
    if i {
        "1"
        "2"
    }
    "3"
    "4"
}

request
{
    {
        "Hello World"
        "こんにちは世界"
    }
    
    "Hallo Welt"
}

request
{
    "Hello"
    "Perfect"
    "Peaceful"
    --
    " Wor"
    --
    "ld"
    "th"
}

"Hello World"
"Perfect World"
"Peaceful World"
"Hello Worth"
"Perfect Worth"
"Peaceful Worth"

• 整数
  符号付き32bit整数です。
  
  10進数値はそのまま記述します。
  先頭に"0b"を付加することにより、2進数値を記述できます。
  先頭に"0x"を付加することにより、16進数値を記述できます。
  
  以下の関数int10は整数10を返します。3つの記述はいずれも10進数では10だからです。

  int10
  {
      10
      0b1010
      0xa
  }
  

• 実数
  符号付き64bit浮動小数点数です。小数点以下の桁がある場合や、精度が落ちてもいいので非常に巨大な数値を扱いたい場合はこれを使用します。
  
  整数との区別は小数点の有無です。文は数値に小数点を見つけると、これを実数として取り扱います。
• 文字列
  ダブルクォート（"）で囲まれた値は文字列です。
  
  文字列の中にダブルクォートが含まれてはいけません。
  
  
• 文字列（展開なし）
  シングルクォート（'）で囲まれた値は、展開されない単純な文字列です。
  文では文字列中に変数や関数を埋め込むことが出来ますが、これが展開されるのはダブルクォートで囲まれた文字列のみです。
  
  文字列の中にシングルクォートが含まれてはいけません。

request
{
    str = "こんにちは"
    
    str
}

request
{
    "Hello World"
    i
}

request
{
    "Hello World"
    ""
}

request
{
    _i = "3*2は"
    
    _j = multi(3)
    
    _i +_j + "です"
}

multi
{
    _i = _argv[0]
    _i * 2
}

request
{
    {
        _str = "Hello World"
    }

    _str
}

演算子　　　　　　　　　　　　　　　　　　　　　　意味　　　　　　　　　　優先度

( )　[ ]　　　　　　　　　　　　　　　　　　　　　ブラケット　　　　　　　高い
!　　　　　　　　　　　　　　　　　　　　　　　　 否定*
++　--　　　　　　　　　　　　　　　　　　　　　　ポストインクリ*/デクリ*
*　/　%　　　　　　　　　　　　　　　　　　　　　 乗除算、剰余
+　-　　　　　　　　　　　　　　　　　　　　　　　加減算
&　　　　　　　　　　　　　　　　　　　　　　　　 フィードバック*
==　!=　>=　<=　>　<　_in_　!_in_　　　　　　　　 比較
&&　　　　　　　　　　　　　　　　　　　　　　　　論理積
||　　　　　　　　　　　　　　　　　　　　　　　　論理和
=　:=　　　　　　　　　　　　　　　　　　　　　　 代入
+=　-=　*=　/=　%=　+:=　-:=　*:=　/:=　%:=　,=　 演算して代入
,       　　　　　　　　　　　　　　　　　　　　　汎用配列要素の列挙　　　低い

コロン（":"）付きの代入演算子は過去互換性を保持するために残されているもので、機能的にはコロン無しのものと同等です。


*は単項演算子です。

foo
{
    "or" _in_ "World"
}

foo
{
    (3+2)*4
}

1+2-3

i = j = 10

i = (j = 10)

"10+2は" + (10+2) + "です。"

answer = (_i = 10) + (2*(_i + 10))

answer = (((_i = 10))) + (2*(_i + 10))

request
{
    _i = 1
    foo(&_i)
}

foo
{
    _argv[0] = 100
}

request
{
    foo(1, 2, &_value, "Hello", &_value2)
    
    _value + _value2
}

foo
{
    _argv[2] = _argv[0] + _argv[1]
    _argv[4] = _argv[3] + " World"
}

request
{
    _a = "this,is,a,pen"
    _a[1]
}

request
{
    "this,is,a,pen"[1]
}

request
{
    "This is a island."[2,"is"]
}

request
{
    _ar = "taro|male,ayame|female,hotaru|female"
	
    _ar[2][1,"|"]
}

request
{
    _a = "this,is,a,pen"
    _a[3] = "eraser"
    _a
}

request
{
    _s = "This is a island."
    _s[2,"is"] = " beautiful "
    _s
}

request
{
    _ar = "taro|male,ayame|female,hotaru|female"
	
    _ar[1][1,"|"] = "male"
}

request
{
    _m = "fuji/asama/tanigawa"
    _m[5,"/"] = "daisen"
    _m
}

request
{
    _m = "fuji/asama/tanigawa"
    SETDELIM(_m, "/")
    _m[5] = "daisen"
    _m
}